/*  makeinkjetpat.aml
/*  aml to make a shadeset optimized for the HP650C
/*    Ralph Haugerud, U.S. Geological Survey
/*    Harvey Greenberg, Geological Sciences, University of Washington
/*    April 1998
/*        rhaugerud@usgs.gov
/*        hgreen@u.washington.edu
/*
/* to be run from ARCPLOT

/* edit following two lines to change linewidths for all symbols
&set thick = .007
&set thin  = .003
/* edit following to change colors that symbols are created in
&set colors = [unquote 'cyan magenta yellow black white red green blue']

&set n = 1 

shadedelete ALL /* clear all current symbols
shadetype randommarker 20 87
shadesize 0.1
shadeseparation 0.03 0.03
shadesize 0.08 0.08
shadecolor brown
shadeput %n%
&call IncrementN

shadecopy from rockpat7.shd 5 %n%
shadesymbol %n%
&call SaveMany

shadecopy from rockpat7.shd 24 %n%
shadesymbol %n%
&call SaveMany

shadecopy from rockpat7.shd 64 %n%
shadesymbol %n%
&call SaveMany

shadecopy from rockpat7.shd 104 %n%
shadesymbol %n%
&call SaveMany

shadecopy from rockpat7.shd 513 %n%
shadesymbol %n%
&call SaveMany

shadecopy from rockpat7.shd 527 %n%
shadesymbol %n%
&call SaveMany

shadecopy from rockpat7.shd 533 %n%
shadesymbol %n%
&call SaveMany

shadelayer 1
shadetype randommarker 35 54
shadeseparation 0.1 0.1
shadesize 0.08 0.08
shadelayer 2
shadetype randommarker 35 54
shadeseparation 0.07 0.07
shadesize 0.02 0.02
shadeput %n%
&call SaveMany


shadetype marker 35 10
shadesize 0.3 0.3
shadeseparation 0 0
shadedeletelayer 2
shadeput %n%
&call SaveMany

shadecopy from rockpat7.shd 585 %n%
shadesymbol %n%
&call SaveMany

shadecopy from rockpat7.shd 511 %n%
shadesymbol %n%
&call SaveMany

shadecopy from rockpat7.shd 573 %n%
shadesymbol %n%
&call SaveMany

&type The maximum shade number is [calc %n% - 1]
&type Use SYMBOLDUMP SHADE SCREEN 1 [calc %n% - 1] '  to view shades.'

shadesave inkjetpat.shd

&return

/*********************
&routine SaveMany 
  shadedelete %n%
  &s n = [calc  [trunc [calc ( %n% + 8 ) / 10]]  * 10 + 1]

  &call ThinShadePen
  &call SaveInColors
  &s n = [calc  [trunc [calc ( %n% + 8 ) / 10]]  * 10 + 1]
  &call ThickShadePen
  &call SaveInColors
  &return


&routine SaveInColors
  &do OneColor &list %colors%
    &s color = %OneColor%
    &call saveOneColor
    &end
  &return
  
&routine saveOneColor
  shadelayer 1
  shadecolor %color%
  shadelayer 2
  shadecolor %color%
  shadeput %n%
  shadelayer 1
  &call IncrementN
  &return

&routine ThickShadePen
  shadelayer 1
  shadepen %thick%
  shadelayer 2
  shadepen %thick%
  shadelayer 1
  &return  
  
&routine ThinShadePen
  shadelayer 1
  shadepen %thin%
  shadelayer 2
  shadepen %thin%
  shadelayer 1
  &return  
  
&routine IncrementN
  &s n = [calc %n% + 1]
  &return
 
&return