/* macro to restore faults to units + contacts layer
/*  WDGER 1:100K geology

&if [exist gunit2 -cover] &then kill gunit2 all

/* 2 problems to solve
/*   First, need to augment arc attributes in gunit.aat
/*   so that interesting fault information can be carried 
/*   in this table. Faults can then be pulled from the gfault
/*   coverage with the Arc GET command 

arcedit
  ec gunit
  ef arc
  additem GFAULT.ID 5 5 I
  additem GFLTSEG.TYPE.CD 3 3 I
  /* Note that these new integer attributes will
  /* have defaults values of 0

  /* Now to get rid of contacts that are also faults, as we 
  /* replace them in the next step
  sel fltcnt = 'Y'
  delete

  /* Set snapping to fix any minor geometry problems 
  /* (there probably aren't any)
  nodesnap closest 30
  /* and GET the fault arcs
  get gfault
  save gunit2
  quit

/* reconnect everything and build polygon topology
clean gunit2 gunit2 30 30

/*   If you were to run
/*      Arc: labelerrors gunit2
/*   you would find that there are lots of polygons
/*   with no labels.  Not surprising: pulling in
/*   these new arcs has chopped up a bunch of polys
/*   but not created any new label points. The work-around
/*   for this is to (a) make polygon topology for the gfault
/*   coverage (we will not use this topology directly but
/*   it must be there), (b) use the UNION (polygon overlay) 
/*   command to combine faults and unit-polygons and make 
/*   new label points that preserve the attributes of the 
/*   gunit polys, and then (c) replace the old, incomplete
/*   set of label points with this new complete set

&if [exist gfault1 -cover] &then kill gfault1 all
copy gfault gfault1
/*  (a) make polygon topology for gfault cover
build gfault1

/*  (b) do the polygon overlay
&if [exist gunit3 -cover] &then kill gunit3 all
union gunit gfault1 gunit3 30

/*   (c) replace old labels with new
ae
  ec gunit2
  ef label
  sel all
  delete
  get gunit3
  save 
  quit

/* create topology
build gunit2

/* clean up
kill gfault1 all
kill gunit3 all

&return

/* If you wish, try
/*     Arc: labelerrors gunit2
/* to see how this worked.